Быстрая смена сетевых настроек с помощью командного файла

Пригодится, если для доступа к сети необходимо менять сетевые настройки. В примере есть и смена MAC-адреса машины.
Чтобы как-то автоматизировать этот процесс, была запущена командная строка и поисковик. Подробности и готовый bat-файл под катом.

Используется 2 утилиты:
netsh - для смены IP в командной строке windows
macshift - для смены MAC-адреса

Собственно, сам файлик:

@echo off
set /p mesto="Выберите настройки (1 - дом, 2 - работа): "
if %mesto% equ 2 goto rabota

:dom
set IFACE="local"
set IP=10.160.100.9
set MASK=255.255.255.0
set GATEWAY=10.160.100.1
set GWMETRIC=1
set DNS1=10.160.100.1
set MAC=001122334455
goto smena

:rabota
set IFACE="local"
set IP=192.168.1.91
set MASK=255.255.255.0
set GATEWAY=192.168.1.1
set GWMETRIC=1
set DNS1=192.168.1.10
set MAC=221133004455
goto smena

:smena
echo Меняем MAC адрес на %MAC%
macshift -i "local" %MAC%

echo Устанавливаем IP адрес-%IP%
echo Маску подсети-%MASK%
echo Основной Шлюз-%GATEWAY%
netsh interface ip set address name=%IFACE% source=static addr=%IP% mask=%MASK% gateway=%GATEWAY% gwmetric=%GWMETRIC%

echo Устанавливаем основной DNS сервер %DNS1%
netsh interface ip set dns name=%IFACE% source=static addr=%DNS1% register=PRIMARY

echo Настройки сети изменены:
pause

Для тех кому лень делать командные файлы - помогут программы TCP/IP Manager, NetSetMan, JIMIP Switcher, Ryll MAC Editor и многие другие из гугла :)
А этот вариант для тех, кому не хочется ради каждого чиха ставить отдельную программу.

Оригинальный вариант с командным файлом подсмотрен на http://habrahabr.ru/blogs/windows/125836/#habracut